copyright 1999 - 2014 by heinz prelle - hannover  - lenbachstraße 42 - www.visual-basic5.de | impressum
'Beispiel: VB .Net - WebBrowser - Mausklick auswerten

'Hinweis: Referenzieren Sie zu: SHDocVw.dll im Systemverzeichnis und zu Microsoft.mshtml
'Klicken Sie zum Testen die einzelnen Elemente auf der geladenen Webseite an.
'
Option Explicit On
Option Strict On

Imports mshtml
Imports SHDocVw

Public Class Form1

    Private HTMLDocument As mshtml.HTMLDocument
    Private Browser As SHDocVw.WebBrowser

    Private Sub InitHandler(ByVal Index As Integer)
        Select Case Index
            Case 1
                Try
                    With Me
                        Browser = DirectCast(.WebBrowser1.ActiveXInstance, SHDocVw.WebBrowser)
                        HTMLDocument = CType(Browser.Document, mshtml.HTMLDocument)
                        AddHandler CType _
                            ( _
                            HTMLDocument,  _
                            mshtml.HTMLDocumentEvents2_Event).onclick, _
                            AddressOf Document1_OnClick
                        AddHandler CType _
                            ( _
                            HTMLDocument,  _
                            mshtml.HTMLDocumentEvents2_Event).onmousedown, _
                            AddressOf Document1_OnMouseDown
                    End With
                Catch ex As Exception
                    MessageBox.Show(ex.Message(), "Info - InitHandler - AddHandler")
                End Try
        End Select
    End Sub

    Private Function Document1_OnClick(ByVal e As mshtml.IHTMLEventObj) As Boolean
        With Me
            .Label1.Text = e.srcElement.tagName.ToString()
            .Label2.Text = e.type.ToString()
        End With
        Return True
    End Function

    Private Sub Document1_OnMouseDown(ByVal e As mshtml.IHTMLEventObj)
        With Me
            Select Case e.button
                Case 1
                    .Label3.Text = e.button.ToString() & " Linker Mouse-Button"
                Case 2
                    .Label3.Text = e.button.ToString() & " Rechter Mouse-Button"
            End Select
        End With
    End Sub

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) _
            Handles Button1.Click
        WebBrowser1.Navigate("http://www.alltheweb.com")
    End Sub

    Private Sub WebBrowser1_DocumentCompleted _
                (ByVal sender As Object, _
                 ByVal e As System.Windows.Forms.WebBrowserDocumentCompletedEventArgs) _
                 Handles WebBrowser1.DocumentCompleted
        InitHandler(1)
    End Sub

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        With Me
            .Text = "WebBrowser - Mausklick auswerten"
            .CenterToScreen()
            .Button1.Text = "Load..."
        End With
    End Sub
End Class
Sourcecode Visual Basic